Initial commit

PKGBUILD

@@ -0,0 +1,45 @@
+# Maintainer: Juanjo Gutiérrez <juanjo@gutierrezdequevedo.com>
+
+pkgname=oldssh
+_sshpkgname=openssh
+_sshpkgver=7.5p1
+_sslpkgname=openssl
+_sslpkgver=1.0.2u
+pkgver=1.0
+pkgrel=1
+pkgdesc="openssh's SSH client version 7.5p1, last one to support SSH v1"
+arch=('x86_64' 'aarch64')
+url="http://www.openssh.com"
+license=('BSD')
+groups=()
+depends=('openssl' 'openssh')
+source=("https://cdn.openbsd.org/pub/OpenBSD/OpenSSH/portable/openssh-7.5p1.tar.gz"
+        "https://www.openssl.org/source/old/1.0.2/openssl-1.0.2u.tar.gz")
+md5sums=('652fdc7d8392f112bef11cacf7e69e23'
+         'cdc2638f789ecc2db2c91488265686c1')
+
+build() {
+    # build openssl
+    cd "$srcdir/${_sslpkgname}-${_sslpkgver}"
+    ./config --prefix=/usr
+    make build_libcrypto
+
+    cd "$srcdir/${_sshpkgname}-${_sshpkgver}"
+    ./configure --prefix=/usr --with-ssh1 --with-ssl-dir="$srcdir/${_sslpkgname}-${_sslpkgver}/"
+
+    # make link to libcrypto static
+    sed -i -e "s#-lcrypto#$srcdir/${_sslpkgname}-${_sslpkgver}/libcrypto.a#g" Makefile
+
+    # make the ssh client use a different directory than openssh
+    sed -i -e "s#\".ssh\"#\".oldssh\"#g" pathnames.h
+
+    make ssh sftp scp
+}
+
+package() {
+    cd "${_sshpkgname}-${_sshpkgver}"
+    install -m 755 -d "$pkgdir"/usr/bin
+    install -m 755 ssh "$pkgdir"/usr/bin/oldssh
+    install -m 755 sftp "$pkgdir"/usr/bin/oldsftp
+    install -m 755 scp "$pkgdir"/usr/bin/oldscp
+}